Asp调用Jmail组件发送邮件

作者:网络 来源:佚名 更新时间:2008-03-26 14:16:05 点击:
在asp程序中用jmail发邮件的比较多,主要是因为多数虚拟主机支持他,其它的支持的较少。下面是一个jmail发邮件的例子代码:

如果您在自己的机器上试,请下载jmail.dll,下载解压后,双击setup.bat 即可完成安装!

<%
on error resume next
dim jmail, contentid
set jmail = server.createobject("jmail.message")
jmail.charset = "gb2312" ' 邮件字符集,默认为"us-ascii"
' jmail.isoencodeheaders = false ' 是否进行iso编码,默认为true

' 发送者信息(可用变量方式赋值)
jmail.from = "[email protected]" ' 发送者地址
jmail.fromname = "海娃" ' 发送者姓名
jmail.subject = "邮件主题" ' 邮件主题

' 身份验证
jmail.mailserverusername = "myusername" ' 身份验证的用户名
jmail.mailserverpassword = "mypassword" ' 身份验证的密码

' 设置优先级,范围从1到5,越大的优先级越高,3为普通
jmail.priority = 3

jmail.addheader "originating-ip", request.servervariables("remote_addr")

' 加入一个收件人【变量email:收件人地址】可以同一语句重复加入多个
jmail.addrecipient("[email protected]")

' 加入附件【变量filename:附件文件的绝对地址,确保用户iusr_机器名有访问的权限】
' 【参数设置是(true)否(false)为inline方式】
'contentid = jmail.addattachment (server.mappath("jmail.asp"), true)

' 邮件主体(html(注意信件内链接附件的方式))
jmail.htmlbody = "<html><head><meta content=zh-cn http-equiv=content-language><meta http-equiv=""content-type"" content=""text/html; charset=gb2312""><style type=text/css>a:link { font-size: 9pt; text-decoration: none; color: #000000}a:visited {font-size: 9pt; text-decoration: none; color: #666666}a:hover {color: #ff6600; font-size: 9pt; text-decoration: underline}body {font-size: 9pt} --></style></head><body><font color=red>邮件正文</font><br><font color=green>邮件正文</font><br><b>邮件正文</b></body></html>"

' 邮件主体(文本部分)
jmail.body = "我们的邮件采用了html格式,但是您的邮件查看软件可能不支持。。。邮件正文,邮件正文,邮件正文"

' 发送【调用格式:objjmail.send([username:[email protected]]smtpserveraddress[:port])】
jmail.send("smtp.163.com")

' 关闭并清除对象
jmail.close()
set jmail = nothing

if err.number<>0 then
response.write "发送发送失败!"
else
response.write "邮件发送成功!"
end if
%>